隔行插入空行，别再一条条敲了！WPS 两个新函数搞定le

大家好，我是墨云轩。

前几天有位老师问我：表格里一列姓名，想隔一行插一个空行，方便打印和裁切，一百多行数据，手动插入插到手抽筋，有没有快一点的办法？

这个问题，我以前分享过老办法——辅助列。排序一搞，空行就出来了。能用，但步骤不少，新手容易排错。

说实话，自从 WPS 版本升级以后，有了新函数，这事儿就变得简单多了。一种是最常见的，隔一行空一行；另一种稍微绕一点，隔几行插一个空行。分开说。

一、先看需求

一列姓名，一共 12 个人：刘备、关羽、张飞、诸葛亮、黄忠、赵云、刘禅、孙尚香、曹操、吕布、夏侯惇、典韦。

我们想让它变成：一个姓名，跟一个空行，一个姓名，跟一个空行。

二、用 EXPAND 把数组扩成两列

在空白单元格输入：

=EXPAND(B2:B13,,2,"")

这个 EXPAND 函数，作用是把数组扩展到指定的行列数。它有四个参数：数组、行数、列数、填充值。

我们的数据是一列，行数不用扩展，所以第二个参数留空；列数让它扩展成 2 列；扩展出来的位置，用空值填充，所以最后填一个空文本 ""。

对勾确认，你会看到姓名变成了一列数据、一列空值的两列。

三、用 TOCOL 转回一列

在刚才的基础上，外面再套一个 TOCOL：

=TOCOL(EXPAND(B2:B13,,2,""))

TOCOL 的作用，是把一个二维数组转换成一列。转换完，就是一个姓名、一个空行，隔行插入空行就完成了。

四、想隔两行插两个空行？改一个数字就行

如果想要每两个空行隔开姓名，也就是隔两行插两个空行，只需要把公式里的 2 改成 3：

=TOCOL(EXPAND(B2:B13,,3,""))

你琢磨一下就明白了：扩成 3 列，就是 1 个姓名列带 2 个空列，转成一列后自然隔两行一个空行。

五、隔两行插一个空行？得换一个新函数

有同学可能要问了：我不要两个空行，我要隔两行插一个空行，也就是每两个姓名后面跟一个空行，怎么办？

这时候 EXPAND 就不够用了，得换 WRAPROWS。

第一步，先把一列数据按每行 2 个分成两列：

=WRAPROWS(B2:B13,2,"")

第二个参数 2 表示分成几列；放不下的异常位置，用 "" 返回空。

第二步，在这个基础上用 EXPAND 扩成 3 列：

=EXPAND(WRAPROWS(B2:B13,2,""),,3,"")

行数不动，列数扩成 3 列，多出来的位置填空值。

第三步，还是老朋友 TOCOL，转成一列：

=TOCOL(EXPAND(WRAPROWS(B2:B13,2,""),,3,""))

敲回车，完成。两个姓名、一个空行，整整齐齐。

六、公式汇总

B2:B13 换成你自己的数据区域就行。

今天的分享就到这里。欢迎留言交流，先谢过各位大佬。

我是墨云轩，热衷分享办公小技巧，边学习，边分享，每天进步一点点！