WPS又新增两个独有函数,快来体验一下吧!

5月底,WPS版本号更新到了17121,本次更新新增了两个WPS独有函数,分别是SHEETSNAME(返回引用中的工作表名称)、BOOKNAME(返回工作薄名称),下面带大家了解下两个函数的具体使用方法。

SHEETSNAME(返回引用中的工作表名称)

函数语法如下图所示

示例1、制作目录

在C5单元格输入公式(无需下拉,自动溢出)

=SHEETSNAME(,1)

在B5单元格输入公式(无需下拉,自动溢出)

=SEQUENCE(ROWS(C5#))

在D5单元格输入公式(需要下拉填充公式)

=IF(C5="","",HYPERLINK("#'"&C5&"'!a1","跳转"))

由于HYPERLINK函数有些特殊,目前WPS使用HYPERLINK函数还不支持动态数组的溢出功能(此问题后期会优化,优化后将支持动态数组溢出)。

示例2、返回连续工作表名(一班~三班)

在C15单元格输入公式(无需下拉,自动溢出)

=SHEETSNAME(一班:三班!A1:A1,1)

也可以根据目录工作表所在位置使用DROP函数删除指定数量的工作表名称,在C15单元格输入公式

=DROP(SHEETSNAME(,1),2)

示例3、汇总多个工作表的明细

在B25单元格输入公式

=LET(x,VSTACK(一班:三班!A2:C99),FILTER(x,TAKE(x,,1)<>""))

使用VSTACK、FILTER函数可以汇总指定多个连续的工作表明细,但是这个公式美中不足的是当新添加工作表后,无法自动汇总,比如在三班工作表后新增加四班工作表后需要修改公式才可以,现在可以使用SHEETSNAME函数获取当前工作薄所有工作表名称,然后取最后一个工作表名,即可动态获取到当前工作薄最后一个工作表的名称,

=TAKE(SHEETSNAME(),,-1)

获取到最后一个工作表名称后,和开始工作表名称拼接成引用字符串,然后使用INDIRECT函数将字符串转引用即可,在B44单元格输入公式。

=LET(x,VSTACK(INDIRECT("'一班:"&@TAKE(SHEETSNAME(),,-1)&"'!A2:C99")),FILTER(x,TAKE(x,,1)<>""))

示例4、汇总多个工作表明细(添加工作表名称)

在B63单元格输入公式。

=REDUCE({"姓名","性别","分数","班级"},DROP(SHEETSNAME(),,2),LAMBDA(x,y,VSTACK(x,LET(arr,INDIRECT("'"&y&"'!A2:C99"),EXPAND(FILTER(arr,TAKE(arr,,1)<>""),,4,y)))))

BOOKNAME(返回工作薄名称)

函数语法如下图所示。

示例1、返回工作薄名称

虽然早期版本使用 CELL函数也可以返回工作簿名称,但是CELL函数返回工作薄名称是包含路径和工作表名的,提取工作薄名称需要很长的公式,随着版本的更新,使用新函数公式也在慢慢变短,直到有了BOOKNAME函数,从此告别嵌套。

早期版本的公式

=MID(CELL("filename",A1),FIND("[",CELL("filename",A1))+1,FIND("]",CELL("filename",A1))-FIND("[",CELL("filename",A1))-1)

中期版本的公式

=CHOOSECOLS(TEXTSPLIT(CELL("filename",A4),{"[","]"}),-2)

中后期版本的公式

=REGEXP(CELL("filename",A7),"(?<=\[).+(?=\])")

以后版本的公式

=BOOKNAME()

17121版本目前官网还没有更新,想提前体验的小伙伴可以点击下方链接下载

下载链接:https://www.kdocs.cn/l/cjaeVAMtafVJ

辽宁省
浏览 1434
8
26
分享
26 +1
16
8 +1
全部评论 16
 
 
打卡
· 江苏省
回复
 
龙潭吹烛
学习
· 上海
回复
 
哈哈
不认真,还真学不会。实用
· 贵州省
回复
zha7090
zha7090

创作者俱乐部成员

对于我来说,都是 要用的时候,再临时抱佛脚
· 广东省
回复
 
庭小歌
学习
· 浙江省
回复
 
阳光
可以用get.workbook()实现,不过好像不太稳定。
· 北京
回复
 
企鹅爱上จุ๊บ北极熊
学习,这两个函数实用。
· 湖南省
回复
 
亂雲飛渡
学习
· 广东省
回复
 
龙潭吹烛
厉害
· 浙江省
回复
 
懒得批爆
懒得批爆

2024年03月优秀创作者

这个公式里 =SHEETSNAME(一班:三班!A1:A1,1) 如果在一班:三班的所有工作表顺序换了,比如顺序换成了【一班,示例,二班,三班】那么示例中的这个公式是提示循环引用还是依照原计算结果?
· 四川省
回复
 
jnow
为啥提示有捆绑软件
· 江苏省
回复
 
清华学弟任泽岩
清华学弟任泽岩

2024年03月优秀创作者

哇哦 太棒了
· 辽宁省
1
回复
 
自愈
· 新疆
1
回复
 
ORIGINAL
学习
· 湖南省
回复
 
水墨染青花
学习
· 四川省
回复