PMC生产计划群：2025年第13周训练题答案分享
优秀创作者
全文约1100字
大家好，我是古老师。今天我将发布2025年第13周PMC生产计划群的“每日一练”题目与答案。本次发布的资料包括每日练习题、对应的正确答案以及对相关考点的详细解析，旨在辅助大家的学习，并作为参考资料使用。
本周的练习题目难度降低，主题集中在PMC关于库存查询欠料数量方面的题目，通过不断的增加约束条件进行难度升级，让计划员、物控员理解欠料的的运算公式及逻辑
周一：根据库存查询欠料数量
题目背景：
在跟单管理中，订单的需求下达后，最基础的模型就是先判断是否有库存，根据库存情况和需求情况进行比对，判断出缺料数量；
考核点：
公式加减
XLOOKUP 函数
动态数组自动扩展函数
填充公式：
F2=XLOOKUP(D2,A:A,B:B,0)
G2=F2-E2
数组公式：
=LET(B,TRIMRANGE(D2:D1000),A,XLOOKUP(B,A:A,B:B,0),HSTACK(A,A-OFFSET(B,,1)))
周二：根据库存和在制数量查询欠料数量
题目背景：
订单需求除了要查询库存现存量，还需要查询生产在制量，也就是一个展望库存，这里需要二次查询，第一次查询库存，第二次查询在制。；
考核点：
XLOOKUP函数
LET 函数
TRIMRANGE 函数
填充公式：
需要锁定单元格，手动填充；
I2=XLOOKUP(G2,$A$2:$A$6,$B$2:$B$6,0)
J2=XLOOKUP(G2,$D$2:$D$6,$E$2:$E$6,0)
K2=I2+J2-H2
数组公式：
虽然是数组公式，不带动态扩展，有数据增加需要手动增加范围；
I2=XLOOKUP(G2:G3,A2:A6,B2:B6,0)
J2=XLOOKUP(G2:G3,D2:D6,E2:E6,0)
K2=I2#+J2#-H2:H3
一键公式：
=LET(B,TRIMRANGE(G2:G1000),A,XLOOKUP(B,A:A,B:B,0),C,XLOOKUP(B,D:D,E:E,0),HSTACK(A,C,A+C-OFFSET(B,,1)))
通过裁剪函数预计范围，加上合并函数与偏移函数进行公式一建动态数组化；
周三：根据库存和在制数量查询欠料数量-1
题目背景：
周二的题目只是完成了基本的查询，当查询欠料的时候遇到不欠料的情况，就需要再次用判断函数进行二次判断，如果数量大于0代表不欠料，小于0则显示负数；
考核点：
XLOOKUP函数
IF函数
TRIMRANGE 裁剪函数
填充公式：手动填充
I2=XLOOKUP(G2,$A$2:$A$6,$B$2:$B$6,0)
J2=XLOOKUP(G2,$D$2:$D$4,$E$2:$E$4,0)
K2=LET(A,I2+J2-H2,IF(A>0,0,A))
数组公式：一键填充
I2=XLOOKUP(G2:G4,A2:A6,B2:B6,0)
J2=XLOOKUP(G2:G4,D2:D4,E2:E4,0)
K2=LET(A,I2#+J2#-H2:H4,IF(A>0,0,A))
一键填充带扩展
=LET(B,TRIMRANGE(G2:G1000),A,XLOOKUP(B,A:A,B:B,0),C,XLOOKUP(B,D:D,E:E,0),D,A+C-OFFSET(B,,1),HSTACK(A,C,IF(D<0,D,0)))
周四：多个需求查询与单个库存计算
题目背景：
订单需求中如果一个产品下达多次，就需要进行汇总后在进行查询计算，此时重点就是需求汇总后再查询
考核点：
UNIUQE 函数
XLOOKUP 函数
GROUBPY 函数等
填充公式：手动填充
H2=UNIQUE(E2:E9)
I2=SUMIFS($F$2:$F$9,$E$2:$E$9,H2)
J2=XLOOKUP(H2,$A$2:$A$6,B2:B6,0)
K2=J2-I2
数组公式：一键填充
H2=GROUPBY(E2:E9,F2:F9,SUM,,0)
J2=XLOOKUP(H2:H3,A2:A6,B2:B6,0)
K2=J2#-I2:I3
一键填充带扩展
H2=LET(B,TRIMRANGE(E2:E1000),C,OFFSET(B,,1),A,HSTACK(GROUPBY(B,C,SUM,,0),XLOOKUP(UNIQUE(B),A:A,B:B)),HSTACK(A,INDEX(A,,3)-INDEX(A,,2)))
周五：多个需求查询多个库存计算欠料
题目背景：
在实际的欠料计算中，需要特别注意汇总与引用的区别，一般情况下，引用是没有重复项，汇总是有重复项，如一个子件存放在不同的车间仓库，此时直接引用就会出现错误了，需要用汇总了。
考核点：
XLOOKUP函数
SUMIFS 函数
UNIUQE 函数
TRIMRANGE 函数
填充公式：手动填充
I2=UNIQUE(F2:F9)
J2=SUMIFS($G$2:$G$9,$F$2:$F$9,I2)
K2=SUMIFS($B$2:$B$11,$A$2:$A$11,I2)
L2=K2-J2
数组公式：一键填充
I2=GROUPBY(F2:F9,G2:G9,SUM,,0)
K2=SUMIFS(B2:B11,A2:A11,I2:I3)
L2=K2#-J2:J3
一键填充带扩展
=LET(B,TRIMRANGE(F2:F1000),C,OFFSET(B,,1),A,HSTACK(GROUPBY(B,C,SUM,,0),VLOOKUP(UNIQUE(B),GROUPBY(A2:A1000,B2:B1000,SUM),2,0)),HSTACK(A,INDEX(A,,3)-INDEX(A,,2)))
以上就是本周关于PMC生产计划的所有题目和答案。希望通过这些练习，大家能够更好地理解PMC工作中的关键概念和计算方法，从而更加高效地处理实际工作中的各种需求。
同时，欢迎大家加入古哥PMC专业群，与更多的同行一起交流经验、共同学习、进步和成长。感谢大家的积极参与和支持！
