问 告别手动拆行！Excel「按箱规拆分」万能模板，小白直接抄作业

前两天分享了一个装箱的套路，有朋友就提出了如果不是整数就不好用了吧，今天我们就来分享一个通用的套路！

▼ 动画演示-函数调用-小白可套用▼

▍装箱思路解析

本次我们就先来解决网友的问题，非整数装箱问题，同时添加上箱号，本次我们不追求Code Golf,主要解决问题！

之前我们分析过，重要/规格，向上取整是可以装的箱数，我们可以通过这个思路解决，基本通用！

有了总箱数，下面的核心就是处理不够一箱的，相当于余数部分，不过考虑到小数MOD可能出现浮点，所以这里我们采用 总重量 - (总箱数 - 1) * 规格 思路

基本思路分析完毕，我们来使用函数实现看一下！

▍函数实现

箱数的拆分大体这样！

=LET(_总箱数,ROUNDUP(B3/C3,0),IF(SEQUENCE(_总箱数)*C3<=B3,C3,B3-(_总箱数-1)*C3))

我们也可以把产品名称和箱号一起加上！这样我们就完成了第一行，更多行，有函数基础的同学都名称要堆，就可以考虑使用REDUCE函数来处理！

我们可以把一行的处理逻辑封装成一个函数，在REDUCE中循环直接调用，这样就不用再考虑逻辑了！

到这里其实非常好了，但是还差一点，如果能像VLOOKUP这样的函数直接调用更方便了

所以我们还需要进一步封装一下！

▍通用函数公式模板

下面提供通用函数模板，S_装箱(A3:A5,B3:B5,C3:C5) 修改内部的三个参数，分别对应 产品名称，重量，规格

=LET(
    S_装箱, LAMBDA(_产品名称, _重量, _规格,
        REDUCE(
            {"产品名称", "箱号", "重量"},
            SEQUENCE(ROWS(_产品名称)),
            LAMBDA(x, y,
                LET(
                    _当前产品, INDEX(_产品名称, y),
                    _当前重量, INDEX(_重量, y),
                    _当前规格, INDEX(_规格, y),
                    _当前总箱数, ROUNDUP(_当前重量 / _当前规格, 0),
                    _当前箱号, SEQUENCE(_当前总箱数),
                    _当前展开, HSTACK(
                        IF({1, 0}, _当前产品, _当前箱号 & "号"),
                        IF(
                            _当前箱号 * _当前规格 <= _当前重量,
                            _当前规格,
                            _当前重量 - (_当前总箱数 - 1) * _当前规格
                        )
                    ),
                    VSTACK(x, _当前展开)
                )
            )
        )
    ),
    S_装箱(A3:A5, B3:B5, C3:C5)
)

当然，如果你通过定义名称使用，就更好好用了！

公式-名称管理器-新建-名称（按自己方便给一个名称即可，比如一键装箱），引用粘贴公式中的LAMBDA部分！

按照参数提示，依次选择对应的三列回车即可，中文提示比普通自带的函数还友好！

我们再来看看整数是否可以！也是完全OK的！同时也规避了部分公式正好整箱无剩余多出0的BUG问题！

▍番外-个人函数库

我会把自己工作和网友的一些高频问题进行封装并中使用过程中迭代和完善，基本已经形成自己的函数库！大家也可以养成这样的习惯！小白暂时自己搞不定的，有需要也可以联系小编按需定制！

配合JSA或者VBA一键导入到自己使用的工作簿中，非常方便！

OK！今天的内容就到这里更多WPS、AI等办公自动化技能，关注小编！

▍个人热帖合集